Defining rates for mineral precipitation

[WJJ]

Hello, I'm trying to define a rate block for calcite precipitation by 1D transport. To do this, I am referring to the manual and phreeqc.dat. In the process, I have encountered a few questions. First, for the phreeqc manual (version2), example of calcite rate block is

Code: [Select]

Calcite
-start
1 rem M = current number of moles of calcite
2 rem M0 = number of moles of calcite initially present
3 rem PARM(1) = A/V, cm^2/mol
4 rem PARM(2) = exponent for M/M0
10 si_cc = SI("Calcite")
20 if (M <= 0 and si_cc < 0) then goto 200
30  k1 = 10^(0.198 - 444.0 / TK )
40  k2 = 10^(2.84 - 2177.0 / TK)
50 if TC <= 25 then k3 = 10^(-5.86 - 317.0 / TK )
60 if TC > 25 then k3 = 10^(-1.1 - 1737.0 / TK )
70  t = 1
80 if M0 > 0 then t = M/M0
90 if t = 0 then t = 1
100 area = PARM(1) * (t)^PARM(2)
110 rf = k1*ACT("H+")+k2*ACT("CO2")+k3*ACT("H2O")
120 rem 1e-3 converts mmol to mol
130 rate = area * 1e-3 * rf * (1 - 10^(2/3*si_cc))
140 moles = rate * TIME
200 SAVE moles
-end
while the example is quite different in version 3, expressed as

Code: [Select]

Calcite
   -start
1   REM   PARM(1) = specific surface area of calcite, cm^2/mol calcite
2   REM   PARM(2) = exponent for M/M0

10  si_cc = SI("Calcite")
20  IF (M <= 0  and si_cc < 0) THEN GOTO 200
30  k1 = 10^(0.198 - 444.0 / TK )
40  k2 = 10^(2.84 - 2177.0 /TK )
50  IF TC <= 25 THEN k3 = 10^(-5.86 - 317.0 / TK)
60  IF TC > 25 THEN k3 = 10^(-1.1 - 1737.0 / TK )
80  IF M0 > 0 THEN area = PARM(1)*M0*(M/M0)^PARM(2) ELSE area = PARM(1)*M
110 rate = area * (k1 * ACT("H+") + k2 * ACT("CO2") + k3 * ACT("H2O"))
120 rate = rate * (1 - 10^(2/3*si_cc))
130 moles = rate * 0.001 * TIME # convert from mmol to mol
200 SAVE moles
   -end
My questions are as follows:
(1) According to the manual, rate expression is r_f*(A0/V)*(M/M0)^n. Why is A0/V equal to PARM(1)*M0 of version3 example??
(2) When I use a rate block example of version 3, how can I consider the precipitation at a mineral-free surface where M0 is zero?
(3) In version 2, the unit of parm(1) is cm^2/L, whereas it is cm^2/mol in version 3. Can I convert units in rate blocks, such as 1/m in version 2 and m^2/mol in version 3? or phreeqc calculates with only specific units?
(4) If there is no way to model precipitation at mineral-free surface using rate block of version 3, is the rate bolck of version 2 available in phreeqc version 3?

Thank you.

[dlparkhurst]

The result of a RATES calculation is to SAVE then number of moles of reaction that occurs in the system over a time period specified by TIME.

In previous versions of PHREEQC we were a little loose on the units. In particular, it was generally assumed that there was 1 liter of solution, whereas with PhreeqcRM, the volume of solution is often equal to the porosity. Further, the volume of solution may be irrelevant if the reaction is dependent only on surface area. Again, the desired quantity from RATES is moles, not moles per liter. In version 3, the surface area parameter is cm^2 per mole of calcite, so moles of calcite times the parameter gives the current surface area.

You can write the RATES expression any way that you want. You can have a neucleation rate that does not depend on surface area, but depends, say, on the volume of solution and degree of supersaturation. I'm sure you can find expressions in the literature.

You can use RATES to define the rate of Calcite reaction. You can use the version 2 RATES definition, or you can write your own modifications. Also note that there is a database kinec_v3.dat from the Carbfix people, and a database phreeqc_rates.dat that implements the rates of Palandri and Kharakha and the rates of Hermanska and other (Carbfix). However, most of the rate expressions in these databases depend on surface area.